# Remove Microsoft Edge (both Chromium and built-in LTSC versions)
{ ... }:
{
  name = "no-edge";
  auditScript = ''
    @echo off
    :: Remove Chromium Edge using its installer
    for /f "delims=" %%i in ('dir /b /ad "C:\Program Files (x86)\Microsoft\Edge\Application" 2^>nul') do (
      if exist "C:\Program Files (x86)\Microsoft\Edge\Application\%%i\Installer\setup.exe" (
        "C:\Program Files (x86)\Microsoft\Edge\Application\%%i\Installer\setup.exe" --uninstall --system-level --force-uninstall
      )
    )
    
    :: Remove Edge Update
    if exist "C:\Program Files (x86)\Microsoft\EdgeUpdate\MicrosoftEdgeUpdate.exe" (
      "C:\Program Files (x86)\Microsoft\EdgeUpdate\MicrosoftEdgeUpdate.exe" /uninstall
    )
    
    :: Remove Edge directories
    rmdir /s /q "C:\Program Files (x86)\Microsoft\Edge" 2>nul
    rmdir /s /q "C:\Program Files (x86)\Microsoft\EdgeUpdate" 2>nul
    rmdir /s /q "C:\Program Files (x86)\Microsoft\EdgeCore" 2>nul

    :: Remove Edge and DevToolsClient SystemApps
    for /d %%d in ("C:\Windows\SystemApps\Microsoft.MicrosoftEdge_*") do (
      takeown /f "%%d" /r /d y >nul 2>nul
      icacls "%%d" /grant Administrators:F /t >nul 2>nul
      rmdir /s /q "%%d" 2>nul
    )
    for /d %%d in ("C:\Windows\SystemApps\Microsoft.MicrosoftEdgeDevToolsClient_*") do (
      takeown /f "%%d" /r /d y >nul 2>nul
      icacls "%%d" /grant Administrators:F /t >nul 2>nul
      rmdir /s /q "%%d" 2>nul
    )
    
    :: Remove Edge AppxPackage for all users (audit mode)
    powershell -Command "Get-AppxPackage -AllUsers *MicrosoftEdge* | Remove-AppxPackage -AllUsers -EA SilentlyContinue"
    
    :: Remove Edge shortcuts
    del /q "%ProgramData%\Microsoft\Windows\Start Menu\Programs\Microsoft Edge.lnk" 2>nul
    del /q "%PUBLIC%\Desktop\Microsoft Edge.lnk" 2>nul
    del /q "%APPDATA%\Microsoft\Internet Explorer\Quick Launch\Microsoft Edge.lnk" 2>nul
    del /q "%APPDATA%\Microsoft\Internet Explorer\Quick Launch\User Pinned\TaskBar\Microsoft Edge.lnk" 2>nul
    
    :: Remove Edge Update scheduled tasks
    schtasks /delete /tn "\MicrosoftEdgeUpdateTaskMachineCore" /f 2>nul
    schtasks /delete /tn "\MicrosoftEdgeUpdateTaskMachineUA" /f 2>nul
    reg add "HKLM\SOFTWARE\Microsoft\EdgeUpdate" /v DoNotUpdateToEdgeWithChromium /t REG_DWORD /d 1 /f
  '';
}