# wrapper function around virt-customize to create custom Linux image from an original OS image
{ pkgs, lib, ... }:
  originalImage: {
    name ? "",
    hostname ? "",
    nameToHostname ? true,
    diskSize ? "",
    smp ? 2,
    memSize ? 1024,
    install ? [],
    run ? "",
    commands ? "",
    debug ? false,
    impure ? true,
    # Linux-only: script to run on first boot (via systemd --firstboot)
    firstboot ? ""
  }:
  let
    originalImageName = lib.strings.removeSuffix "-vmix" (lib.strings.removeSuffix ".qcow2" originalImage.name);
    customImageName = (if name != "" then name else "custom") + "-${originalImageName}-vmix.qcow2";
    resultImg = "./disk.qcow2";

    setHostname = if hostname != "" then hostname else if nameToHostname then name else "";
    virtCustomizeArgsHostname = if setHostname != "" then "--hostname '${setHostname}'" else "";

    virtCustomizeArgsInstall = if install != [] then "--install '${lib.strings.concatStringsSep "," install }'" else "";
    virtCustomizeArgsCommandsFile = if commands != "" then  ("--commands-from-file " + pkgs.writeText "${name}-virt-customize-commands-file" commands) else "";
    virtCustomizeArgsRun = if run != "" then ("--run " + pkgs.writeScript "${name}-virt-customize-run-script" "${run}") else "";

    virtCustomizeArgsFirstboot = lib.optionalString (firstboot != "")
      ("--firstboot " + pkgs.writeScript "${name}-firstboot" firstboot);

    builderCommand = ''
      export PATH="${pkgs.qemu}/bin:${pkgs.curl}/bin:$PATH"

      # create resulting image backed by original image
      qemu-img create -f qcow2 -b ${originalImage} -F qcow2 ${resultImg}
      [ -n "${diskSize}" ] && qemu-img resize ${resultImg} ${diskSize}

      # run script inside image using virt-customize
      export LIBGUESTFS_APPEND="ipv6.disable=1"

      ${pkgs.guestfs-tools}/bin/virt-customize \
        ${lib.optionalString debug "-v"} \
        -a ${resultImg} \
        --smp ${builtins.toString smp} \
        --memsize ${builtins.toString memSize} \
        ${virtCustomizeArgsHostname} \
        ${virtCustomizeArgsInstall} \
        ${virtCustomizeArgsFirstboot} \
        ${virtCustomizeArgsCommandsFile} \
        ${virtCustomizeArgsRun}

      mv ${resultImg} $out
    '';

  builtImage = pkgs.runCommand customImageName (lib.optionalAttrs impure { __noChroot = true; }) builderCommand;
  in
    builtImage // { _vmixOsType = "linux"; }