# wrapper function around virt-customize to create custom OS image from an original OS image
{ pkgs, lib, ... }:
  originalImage: {
    name ? "",
    hostname ? "",
    nameToHostname ? true,
    diskSize ? "",
    smp ? 2,
    memSize ? 1024,
    install ? [],
    run ? "",
    commands ? "",
    osType ? "linux"
  }:
  let
    originalImageName = lib.strings.removeSuffix "-vmix" (lib.strings.removeSuffix ".qcow2" originalImage.name);
    customImageName = (if name != "" then name else "custom") + "-${originalImageName}-vmix.qcow2";
    resultImg = "./disk.qcow2";

    qemuWrapperScript = (pkgs.writeShellScript "qemu-wrapper-script" ''
      export PATH="${pkgs.qemu}/bin:$PATH"
      exec qemu-kvm -nic user,model=virtio-net-pci "$@"
    '');

    setHostname = if hostname != "" then hostname else if nameToHostname then name else "";
    virtCustomizeArgsHostname = if setHostname != "" then "--hostname '${setHostname}'" else "";

    virtCustomizeArgsInstall = if install != [] then "--install '${lib.strings.concatStringsSep "," install }'" else "";
    virtCustomizeArgsCommandsFile = if commands != "" then  ("--commands-from-file " + pkgs.writeText "${name}-virt-customize-commands-file" commands) else "";
    virtCustomizeArgsRun = if run != "" then ("--run " + pkgs.writeScript "${name}-virt-customize-run-script" "${run}") else "";

    builderCommand = ''
      export PATH="${pkgs.qemu}/bin:${pkgs.curl}/bin:$PATH"

      # create resulting image backed by original image
      qemu-img create -f qcow2 -b ${originalImage} -F qcow2 ${resultImg}
      [ -n "${diskSize}" ] && qemu-img resize ${resultImg} ${diskSize}

      # run script inside image using virt-customize
      export LIBGUESTFS_APPEND="ipv6.disable=1"
      #export LIBGUESTFS_HV="${qemuWrapperScript}"

      ${pkgs.guestfs-tools}/bin/virt-customize \
        -a ${resultImg} \
        --smp ${builtins.toString smp} \
        --memsize ${builtins.toString memSize} \
        ${virtCustomizeArgsHostname} \
        ${virtCustomizeArgsInstall} \
        ${virtCustomizeArgsCommandsFile} \
        ${virtCustomizeArgsRun}

      mv ${resultImg} $out
    '';
  in
    pkgs.runCommand customImageName { __noChroot = true; } builderCommand